OsvvmScriptsTranslate.tcl

#  File Name:         OsvvmScriptsFileCreate.tcl
#  Purpose:           Scripts for running simulations
#  Revision:          OSVVM MODELS STANDARD VERSION
#
#  Maintainer:        Jim Lewis      email:  jim@synthworks.com
#  Contributor(s):
#     Jim Lewis           email:  jim@synthworks.com
#     Markus Ferringer    Patterns for error handling and callbacks, ...
#
#  Description
#    Tcl procedures to Autogenerate Files
#
#  Developed by:
#        SynthWorks Design Inc.
#        VHDL Training Classes
#        OSVVM Methodology and Model Library
#        11898 SW 128th Ave.  Tigard, Or  97223
#        http://www.SynthWorks.com
#
#  Revision History:
#    Date      Version    Description
#     1/2025   2025.01    Initial
#
#
#  This file is part of OSVVM.
#
#  Copyright (c) 2025 by SynthWorks Design Inc.
#
#  Licensed under the Apache License, Version 2.0 (the "License");
#  you may not use this file except in compliance with the License.
#  You may obtain a copy of the License at
#
#      https://www.apache.org/licenses/LICENSE-2.0
#
#  Unless required by applicable law or agreed to in writing, software
#  distributed under the License is distributed on an "AS IS" BASIS,
#  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
#  See the License for the specific language governing permissions and
#  limitations under the License.
#

package require fileutil
package require huddle
package require yaml

namespace eval ::osvvm {
  # Declare existance as a global, but do not initialize as it will clear it
  variable AnalyzeDict  
  variable AnalyzeOrderList 
  variable SimulateDict 

# -------------------------------------------------
# CreateDryRunDict
#
proc CreateDryRunDict {ProFileToBuild} {
  # CreateDryRunDict runs a build script in DryRunMode and 
  # creates dictionaries and lists of Analyze and Simulate information.
  # The Analyze dictionary, ::osvvm::AnalyzeDict, has a dictionary
  # for each library used.  For each library there is an list of 
  # dictionaries that contain the file analyzed as well as language version used.
  # The list, ::osvvm::AnalyzeOrderList, has a list of dictionaries 
  # that contain the file name, library, and vhdl version.
  # The Simulation dictionary, ::osvvm::SimulateDict, has a dictionary
  # for each library used.  For each library there is an list of 
  # dictionaries that contain information passed to simulate.
	#
  #  ProFileToBuild - Path to the pro file that build the entire design.
  #  WhereToCreate  - Directory into which to create vhdl_ls.toml.  Default = .
	#
  
  variable GenerateOsvvmReports
  set SavedGenerateOsvvmReports $GenerateOsvvmReports
  set GenerateOsvvmReports "false"   ;# turn off reports
 
  # initialize dictionaries to empty
  variable AnalyzeDict  [dict create]  ;# empty dictionary
  variable AnalyzeOrderList ""         ;# empty list
  variable SimulateDict [dict create]  ;# empty dictionary
  
  # Create AnalyzeDict and SimulateDict as a recording of 
  source $::OsvvmLibraries/Scripts/VendorScripts_DryRunDict.tcl
  
  build $ProFileToBuild [BuildName CreateDryRunDict]
#  if {$ScriptToRun ne ""} { $ScriptToRun }
  
  # restore settings and tool API actions
  # StartUp  ;# replace source below with StartUp if features beyond VendorScripts_xxx.tcl are changed
  source $::OsvvmLibraries/Scripts/VendorScripts_${::osvvm::ScriptBaseName}.tcl
  set GenerateOsvvmReports $SavedGenerateOsvvmReports  ;# restore reports
}

# -------------------------------------------------
# CreateVhdlLsToml for VHDL LS
#
proc CreateVhdlLsToml {ProFileToBuild {FileNameAndPath "./vhdl_ls.toml"}} {
  # CreateVhdlLsToml runs a build script in DryRunMode and 
  # creates a vhdl_ls.toml file.
	#
  #  ProFileToBuild - Path to the pro file that build the entire design.
  #  FileNameAndPath  - Name of file to create.  Default:  ./vhdl_ls.toml
	#
  variable AnalyzeDict

  # Create AnalyzeDict for the ProFileToBuild script
  CreateDryRunDict $ProFileToBuild

  set TomlFile      [open [file normalize $FileNameAndPath] w]

  puts $TomlFile "# Generated by OSVVM's CreateVhdlLsToml"
  puts $TomlFile "\[libraries\]"

  foreach key [dict keys $AnalyzeDict] {
    # Print library name
    set FileList [dict get $AnalyzeDict $key]
    puts $TomlFile "${key}.files = \["
    foreach FileDict $FileList {
      puts $TomlFile "  '[dict get $FileDict FileName]',"
    }
    puts $TomlFile "\]"
    # mark things from OSVVM libraries as thrid party
  }
  close $TomlFile
}

proc CreateAnalyzeOrderCsv {ProFileToBuild {FileNameAndPath "./AnalyzeOrder.csv"}} {
  # CreateAnalyzeOrderCsv runs a build script in DryRunMode and 
  # creates a AnalyzeOrder.csv file.
	#
  #  ProFileToBuild  - Path to the pro file that build the entire design.
  #  FileNameAndPath - Name of file to create.  Default:  ./AnalyzeOrder.csv  
	#
  variable AnalyzeOrderList

  # Create AnalyzeDict for the ProFileToBuild script
  CreateDryRunDict $ProFileToBuild

  set CsvFile     [open [file normalize $FileNameAndPath] w]

#  puts $CsvFile "# Generated by OSVVM's CreateAnalyzeOrderCsv"

  foreach FileDict $::osvvm::AnalyzeOrderList {
    if {[info exists PrintString]} {puts $CsvFile "${PrintString},"}
    set PrintString [dict get $FileDict FileName]
    # puts $CsvFile "[dict get $FileDict FileName],"
  }
  puts $CsvFile "${PrintString}"
  close $CsvFile 
}

proc ProToYaml {ProFileToBuild {FilePath "."}} {
  # ProToYaml runs a build script in DryRunMode and 
  # creates a Analyze.yaml and Simulate.yaml file.
	#
  #  ProFileToBuild  - Path to the pro file that build the entire design.
  #  FilePath        - Path to Analyze.yaml and Simulate.yaml
	#

  # Create AnalyzeDict and SimulateDict for the ProFileToBuild script
  variable AnalyzeDict
  variable SimulateDict
  CreateDryRunDict $ProFileToBuild

  set ProFileName [file rootname [file tail $ProFileToBuild]]

  # Convert Analyze Dict to Yaml via Huddle
  # {library [file {name language_ver}]}
  set AnalyzeHud [huddle compile {dict * {list {dict}}} $::osvvm::AnalyzeDict]
  set    AnalyzeYamlFile   [open [file join $FilePath "${ProFileName}_Analyze.yml"] w]
  puts  $AnalyzeYamlFile   [yaml::huddle2yaml $AnalyzeHud]
  close $AnalyzeYamlFile

  # Convert Simulate Dict to Yaml via Huddle
  # {library [file {name language_ver}]}
  set SimulateHud [huddle compile {dict * {list {dict}}} $::osvvm::SimulateDict]
  set    SimulateYamlFile   [open [file join $FilePath "${ProFileName}_Simulate.yml"] w]
  puts  $SimulateYamlFile   [yaml::huddle2yaml $SimulateHud]
  close $SimulateYamlFile
}

proc ProToJson {ProFileToBuild {FilePath "."}} {
  # ProToJson runs a build script in DryRunMode and 
  # creates a Analyze.json and Simulate.json file.
	#
  #  ProFileToBuild  - Path to the pro file that build the entire design.
  #  FilePath        - Path to Analyze.json and Simulate.json
	#

  # Create AnalyzeDict and SimulateDict for the ProFileToBuild script
  variable AnalyzeDict
  variable SimulateDict
  CreateDryRunDict $ProFileToBuild

  set ProFileName [file rootname [file tail $ProFileToBuild]]

  # Convert Analyze Dict to Yaml via Huddle
  # {library [file {name language_ver}]}
  set AnalyzeHud [huddle compile {dict * {list {dict}}} $::osvvm::AnalyzeDict]
  set    AnalyzeJsonFile   [open [file join $FilePath "${ProFileName}_Analyze.json"] w]
  puts  $AnalyzeJsonFile   [huddle jsondump $AnalyzeHud]
  close $AnalyzeJsonFile

  # Convert Simulate Dict to Yaml via Huddle
  # {library [file {name language_ver}]}
  set SimulateHud [huddle compile {dict * {list {dict}}} $::osvvm::SimulateDict]
  set    SimulateJsonFile   [open [file join $FilePath "${ProFileName}_Simulate.json"] w]
  puts  $SimulateJsonFile   [huddle jsondump $SimulateHud]
  close $SimulateJsonFile
}


# Don't export the following due to conflicts with Tcl built-ins
# map

namespace export CreateDryRunDict
namespace export CreateVhdlLsToml
namespace export CreateAnalyzeOrderCsv
namespace export ProToYaml
namespace export ProToJson


# end namespace ::osvvm
}